big changes

2 files changed, 100 insertions, 0 deletions

diff --git a/modules/desktop/system/programs/firefox.nix b/modules/desktop/system/programs/firefox.nix
new file mode 100644
index 0000000..e5c5e21
--- /dev/null
+++ b/modules/desktop/system/programs/firefox.nix
@@ -0,0 +1,36 @@
+{
+  lib,
+  config,
+  ...
+}: let
+  cfg = config.collinux.desktop.programs.firefox;
+in
+  lib.mkIf cfg.enable {
+    programs.firefox = {
+      enable = true;
+      policies = {
+        PasswordManagerEnabled = false; # use bitwarden instead
+        DisableAccounts = true;
+        DisablePocket = true;
+
+        OverrideFirstRunPage = "";
+        OverridePostUpdatePage = "";
+
+        ExtensionSettings = let
+          ext = name: {
+            installation_mode = "force_installed";
+            install_url = "https://addons.mozilla.org/firefox/downloads/latest/${name}/latest.xpi";
+          };
+        in
+          lib.mkMerge [
+            {
+              "{446900e4-71c2-419f-a6a7-df9c091e268b}" = ext "bitwarden-password-manager";
+              "uBlock0@raymondhill.net" = ext "uBlock0@raymondhill.net";
+            }
+            (lib.mkIf (cfg.theme == "catppuccin") {
+              "{88b098c8-19be-421e-8ffa-85ddd1f3f004}" = ext "catppuccin-mocha-blue";
+            })
+          ];
+      };
+    };
+  }
diff --git a/modules/desktop/system/programs/foot.nix b/modules/desktop/system/programs/foot.nix
new file mode 100644
index 0000000..d6f97c7
--- /dev/null
+++ b/modules/desktop/system/programs/foot.nix
@@ -0,0 +1,64 @@
+{
+  pkgs,
+  config,
+  lib,
+  ...
+}: let
+  cfg = config.collinux.desktop.programs.foot;
+  ini' = pkgs.formats.ini {listsAsDuplicateKeys = true;};
+
+  settings = ini'.generate "foot.ini" {
+    main = {
+      font = "Iosevka Nerd Font:size=12";
+      shell =
+        if config.collinux.terminal.programs.tmux.enable
+        then "${pkgs.tmux}/bin/tmux"
+        else "${pkgs.fish}/bin/fish";
+    };
+
+    cursor.color = "11111b f5e0dc";
+    colors = {
+      foreground = "cdd6f4";
+      background = "1e1e2e";
+
+      regular0 = "45475a";
+      regular1 = "f38ba8";
+      regular2 = "a6e3a1";
+      regular3 = "f9e2af";
+      regular4 = "89b4fa";
+      regular5 = "f5c2e7";
+      regular6 = "94e2d5";
+      regular7 = "bac2de";
+
+      bright0 = "585b70";
+      bright1 = "f38ba8";
+      bright2 = "a6e3a1";
+      bright3 = "f9e2af";
+      bright4 = "89b4fa";
+      bright5 = "f5c2e7";
+      bright6 = "94e2d5";
+      bright7 = "a6adc8";
+
+      "16" = "fab387";
+      "17" = "f5e0dc";
+
+      selection-foreground = "cdd6f4";
+      selection-background = "414356";
+
+      search-box-no-match = "11111b f38ba8";
+      search-box-match = "cdd6f4 313244";
+
+      jump-labels = "11111b fab387";
+      urls = "89b4fa";
+    };
+  };
+in
+  lib.mkIf cfg.enable {
+    hjem.users."${config.collinux.user.name}" = {
+      files = {
+        ".config/foot/foot.ini".source = settings;
+      };
+
+      packages = [pkgs.foot];
+    };
+  }